많이 사용하는 지표인 Stochastic RSI 지표를 예시로
지표식 작성 흐름을 알아 보겠습니다.
1.
새수식 클릭
수식편집기 오른쪽 상단에서 [새수식]을 클릭합니다.
2.
새 수식 만들기에서 수식 종류와 이름 지정.
새수식을 클릭하면 수식종류 이름을 지정하는 [새 수식 만들기]화면이 나타납니다.
종류는 [지표]로 선택하고 수식명을 입력하고 확인버튼을 클릭합니다.
작성예에서는 StochRSI로 지정했습니다.
3.
지표 편집창
수식 입력하는편집창이 나타나면 수식을 입력합니다.
수식 작성에서 필요한 지표나 계산식에 대한 함수가 제공되면 해당 함수를 사용하고
함수로 제공되지 않으면 직접 계산식을 만들어 사용합니다.
Stochastic RSI 지표공식
Stochastic RSI지표는 기존 스토케스틱에 계산에 가격데이터 대신에 RSI를 사용한 지표입니다.
RSIfastK = (RSIV - 일정기간RSI최저가)/(일정기간RSI최저가 - 일정기간 RSI최고가)*100
RSISlowK = RSIfastK의 일정기간 평균
RSISlowD = RSISlowK의 일정기간 평균
Stochastic RSI는 기본으로 제공되는 함수가 없으므로 수식 안에서 계산식을 만들어 사용합니다.
Stochastic RSI 지표를 작성하면 아래와 같습니다.
//외부변수 선언
input : RSIPeriod(14);
input : FKLength(5);
input : smoothK(5);
input : smoothD(3);
//내부변수 선언
var : R(0),HV(0),LV(0);
var : FK(0),SK(0),SD(0);
//1. RSI 계산(RSI값을 리턴하는 함수가 있으므로 함수를 이용).
//RSI의 기간은 외부변수 처리해서 속성에서 변경가능하게 함.
R = RSI(RSIPeriod);
//2. RSI의 일정기간 최고값/최저값 계산
//기간은 기간은 외부변수 처리해서 속성에서 변경가능하게 함.
Hv = highest(R,FKLength);
Lv = Lowest(R,FKLength);
//3. RSI FastK값 계산
//(RSI- 일정기간RSI최저가)/(일정기간RSI최고가 - 일정기간RSI최저가)*100
FK = (R-LV)/(HV-LV)*100;
//4. RSI SlowK 계산 (FastK의 일정기간 이동평균)
SK = ma(FK, smoothK);
//5. RSI SlowD 계산 (SlowK의 일정기간 이동평균)
SD = ma(SK, smoothD);
//6. 지표 출력
plot1(SK, "K", Red);
plot2(SD, "D", Blue);
PlotBaseLine1(80, "Upper Band", Gray);
PlotBaseLine2(20, "Lower Band", Gray);
C
복사
※ 수식의 내용은 전체를 복사해서 편집창에 붙여넣기 하시면 됩니다.
※ 주석을 통해 수식 내용을 확인하시기 바랍니다.
4.
저장 혹은 차트적용
수식 작성이 완료되면 편집기 오른쪽 상단에서 [저장] 혹은 [차트적용]을 누르면
자동으로 문법검증과 함께 수식이 저장됩니다.
저장은 수식을 저장만 하고 차트적용은 저장과 동시에 차트에 지표를 표시합니다.
5.
속성설정
지표식 작성 완료 후에 속성창에서
그래프 외형이나 , 지표 사이 채우기, 지표 적용영역 등을 설정을 할 수 있습니다.
표시탭에서 그래프 모양이나 색상, 굵기 등 지표 외형에 대한 설정을 할 수 있습니다.
채우기탭에서는 2개 지표를 비교해서 지표 사이에 지정한 색으로 채우기를 할 수 있습니다.
적용영역탭에서는 해당 지표가 차트에 적용되는 위치를 지정할 수 있습니다.
6.
작성된 지표식은내수식의 지표목록으로 추가됩니다.
뒤로가기는 좌측상단의 목차 버튼을 눌러주세요.