CCI_TA

함수설명

CCI(Commodity Channel Index) 지표함수. ※기존 CCI함수는 기간만 지정이 가능하고 계산의 기준값들은 지정할 수 없었지만 CCI_TA함수는 기준값을 다른 값으로 지정해 계산할 수 있습니다.

작성방법

CCI_TA(Hprice, Lprice, Cprice, 기간)
C
복사

매개변수 설명

•

"Hprice": Numeric, 데이터, 함수, 변수, 계산식 등, 계산식에서 고가로 사용할 값

•

"LPrice": Numeric, 데이터, 함수, 변수, 계산식 등, 계산식에서 저가로 사용할 값

•

"CPrice": Numeric, 데이터, 함수, 변수, 계산식 등, 계산식에서 종가로 사용할 값

•

"기간": Numeric,  최근 N개봉 기간값을 입력

계산

기준값 = 고가+저가+종가 M1 = 기준값의 N기간 이동평균값 M2 = (기준값-M1)의 절대값의 N기간 이동평균값 CCI = (기준값-M1)/(M2*0.015)

활용예시

1.
value1 = ma(C,5)
var1 = CCI_TA(value1,value1,value1,10); 
--> 5기간 단순이동평균으로 계산한 CCI값을 var1에 저장에 저장

2.
//인라인함수(수식안에서 만들어 사용하는 함수)
Function infx_CCI_TA Numeric 
{
	Input : HPrice(NumericSeries),LPrice(NumericSeries),CPrice(NumericSeries),Length(NumericSimple);
	var : Price(0),Sum(0), Counter(0), MD(0), Avgvalue(0);

	If Length > 0 Then
	{
		Price =  HPrice+LPrice+CPrice;
		Avgvalue = Ma(Price, Length);
		MD = 0;
		For counter = 0 To Length - 1 Begin
			MD = MD + Abs(Price[counter] - Avgvalue);
		End;
		MD = MD / Length;
		If MD == 0 Then 
			infx_CCI_TA = 0; 
		Else
			infx_CCI_TA = (Price - Avgvalue) / (0.015 * MD);
	}
	Else 
		infx_CCI_TA = 0;
}
EndFunction

Input : Period(9),signal(10),과매수(100),과매도(-100);
var : CCIv(0),CCIs(0);

value1 = ma(C,5);
CCIv = infx_CCI_TA(value1,value1,value1,Period);
CCIs = ma(CCIv,Signal);
	
Plot1(CCIv, "CCI");
Plot2(CCIs, "CCI Signal");
PlotBaseLine1(과매수, "과매수");
PlotBaseLine2(과매도, "과매도");
C
복사

뒤로가기는 좌측상단의 목차 버튼을 눌러주세요.