#공통, 지표
[설명]
RCI(Rank Correlation Index)는 순위상관지수라고도 불리는데 지표로
가격 움직임의 방향성 일관성을 측정하는 데 도움을 주는 오실레이터입니다.
이는 주어진 과거 기간 내에서 가격이 일정 방향 추세를 얼마나 밀접하게 따르는지 평가합니다.
가격 수준의 차이에 의존하는 모멘텀 오실레이터와 달리,
RCI는 바 인덱스와 가격 순위 간의 상관관계를 측정하므로 가격의 절대값보다는
상대적 순서에 민감합니다.
RCI는 특정 기간 동안 가격과 바 지수 간의 스피어먼 순위상관계수를 스케일링한 값을 나타냅니다. RCI 값을 계산하기 위해 지표는 다음과 같이 작동합니다:
1.
가격을 순서대로 정렬하여 오름차순으로 배열합니다. 정렬된 각 가격의 위치는 초기 순위를 나타냅니다. 최저 가격은 순위 0을 가지며, 최고 가격의 순위는 N - 1입니다(N은 기간 내 바 수). 예를 들어, 분석 대상 가격이 10, 12, 15, 12인 경우 초기 순위는 각각 0, 1, 3, 2입니다.
2.
동점 시 순위 조정. 두 개 이상의 가격이 동일할 경우, 각 가격에 정렬된 위치의 평균값을 최종 순위로 할당합니다. 예를 들어, 이전 단계에서 제시된 가상의 가격에 대한 최종 순위는 0, 1.5, 3, 1.5입니다. 순위가 1과 2인 값이 동일하고, 1과 2의 평균은 1.5이기 때문입니다.
3.
가격 순위와 바 인덱스의 시퀀스 간 상관 계수를 계산한 후 해당 값에 100을 곱합니다.
결과는 -100에서 +100 사이를 움직이는 오실레이터입니다.
•
+100 값은 분석 기간 동안 가격이 지속적으로 상승했음을 나타냅니다
•
100 값은 해당 기간 동안 가격이 지속적으로 하락했음을 나타냅니다
0에 가까운 값은 해당 기간 동안 가격에 방향 일관성이 거의 없거나 전혀 없음을 나타냅니다.
//인라인 함수(수식내에서 함수정의)
Function RCI Numeric
{
input : Price(Numeric);
input : Length(Numeric);
var : d(0),i(0),ii(0),p(0),ov(0),s(0),ord(0);
d = 0;
For i = 0 to Length - 1
{
p = Price[i];
ov = 1;
s = 0;
for ii = 0 to Length - 1
{
if p < Price[ii] Then
{
ov = ov + 1;
}
else
{
if p == Price[ii] Then
s = s + 1;
}
}
ord = ov + (s - 1) / 2.0;
d = d + pow((i + 1) - ord, 2);
}
RCI = (1.0 - 6.0 * d / (Length * (Length * Length - 1.0))) * 100.0;
}
EndFunction
input : shortLength(10),middleLength(30),longLength(50);
var : ShortRCI(0),MidRCI(0),LongRCI(0);
ShortRCI = RCI(C,shortLength);
MidRCI = RCI(C,middleLength);
LongRCI = RCI(C,longLength);
plot1(ShortRCI, "RCI1",Blue);
plot2(MidRCI, "RCI2",Red);
plot3(LongRCI, "RCI3",Green);
PlotBaseLine1(0, "Middle band",Gray);
PlotBaseLine2(80, "Upper band",Gray);
PlotBaseLine3(-80, "Lower band",Gray);
JavaScript
복사