종목검색은 종목검색화면에서 실행하는 수식으로
특정 조건이 만족하는 종목을 찾는 수식입니다.
아래 작성예에서는 StochRSI 지표를 이용해서
RSI slowk와 RSI slowD의 교차하는 종목을 찾는 식을 작성합니다.
JavaScript
복사
1.
새로운 강조식 편집창 열기
아래 2가지 방법 중 하나 선택해서 새로 만들기 시작하시면 됩니다.
a.
편집기 상단 파일메뉴 → 새로만들기 → 일반탭에서 종목검색 아이콘 선택 → 확인
b. 파일관리자 → 종목검색 선택 → 상단 파일관리도구에서 새수식 아이콘 클릭
2.
강조식 이름 지정.
[강조 새로 작성화면]이 나타나면 이름을 입력하고 확인 버튼을 클릭합니다.
이름은 임의로 지정하시면 되며 작성예에서는 StochRSI Cross로 지정합니다.
3.
종목검색 편집창
수식 입력하는 편집창이 나타나면 수식을 입력합니다.
수식을 작성할 때, 작성하고자 하는 기술적 지표나 계산식에 대한 함수가 제공되면
해당 함수를 사용하면 되고 함수로 제공되지 않으면 직접 계산식을 만들어 사용합니다.
지표공식
StochRSI = (RSIV - 일정기간 RSI최저가)/(일정기간 RSI최저가-일정기간 RSI최고가)*100
Stochastic RSI지표는 RSI의 N기간 최고가와 최저가 기준으로
현재 RSI의 수준을 나타내는 지표입니다.
Stochastic 공식에 주가 대신 RSI를 대입하여 구하며 결과값은 0~100을 가지게 됩니다.
Stochastic RSI는 기본으로 제공되는 함수는 없으므로 수식 안에서 계산식을 만들어 사용합니다.
먼저 RSI를 계산하고 RSI값의 일정기간 최고가와 최저가를 계산한 후
해당 값들을 이용해서 StochRSI를 계산하면 됩니다.
RSI는 기본으로 함수가 제공되므로 함수를 이용하고,
일정기간 최고가와 최저가도 highest,Lowest함수를 사용해 계산하면 됩니다.
Stochastic RSI 지표를 작성하면 아래와 같습니다.
수식의 내용은 전체를 복사해서 편집창에 붙여넣기 하시면 됩니다.
//외부변수 선언
input : RSIPeriod(14);
input : FKLength(5);
input : smoothK(5);
input : smoothD(3);
//내부변수 선언
var : R(0),HV(0),LV(0);
var : FK(0),SK(0),SD(0);
//1. RSI 계산(RSI값을 리턴하는 함수가 있으므로 함수를 이용).
//RSI의 기간은 외부변수 처리해서 속성에서 변경가능하게 함.
R = RSI(RSIPeriod);
//2. RSI의 일정기간 최고값/최저값 계산
//기간은 기간은 외부변수 처리해서 속성에서 변경가능하게 함.
Hv = highest(R,FKLength);
Lv = Lowest(R,FKLength);
//3. RSI FastK값 계산
//(RSI- 일정기간RSI최저가)/(일정기간RSI최고가 - 일정기간RSI최저가)*100
FK = (R-LV)/(HV-LV)*100;
//4. RSI SlowK 계산 (FastK의 일정기간 이동평균)
SK = ma(FK, smoothK);
//5. RSI SlowD 계산 (SlowK의 일정기간 이동평균)
SD = ma(SK, smoothD);
//6. SlowK가 SlowD를 상향돌파하는 종목찾기
if CrossUp(SK,SD) Then
Find(1);
C
복사
※ 주석을 통해 수식 내용을 확인하시기 바랍니다.
4.
문법 검증
수식 작성이 되었으면 마지막에 문법검증을 실행합니다.
상단 편집도구에서 
를 누르거나 키보드에서 F4키를 누르면 문법검증이 실행됩니다.
혹은 수식 위에서 마우스 우클릭하면 나오는 메뉴에서 검증 선택해 진행해도 됩니다.
를 누르거나 키보드에서 F4키를 누르면 문법검증이 실행됩니다.
혹은 수식 위에서 마우스 우클릭하면 나오는 메뉴에서 검증 선택해 진행해도 됩니다.
문법검증 후 오류창에 [검증이 완료 되었습니다.]라는 메시지가 출력되면
해당 수식에 문법상 오류없이 작성되었고 자동으로 저장됩니다.
5.
속성 설정
색상, 형태 크기를 변경할 수 있습니다.
※ plot함수에 색상, 굵기가 지정되어 있으면 속성에서 변경되지 않습니다.
강조 속성창은 수식 위에서 F5키를 누르거나 편집도구에서 
을 클릭하면 나타납니다.
을 클릭하면 나타납니다.•
변수
수식에서 사용한 input변수의 값을 변경할 수 있습니다.
변수명을 더블클릭하거나 변수를 선택 후 하단 변수 편집 버튼을 누르시면
변수값 변경창이 나타납니다.
•
검색기간
종목검색식 계산에 필요한 봉수를 지정합니다.
※ 검색에 필요한 최소 기간
봉수를 지정하지 않으면 종목검색식 계산에 필요한 최소봉수가
자동으로 계산되서 종목검색을 수행합니다.
수식 내용에 따라 봉수를 산정하지 못하는 경우도 있고
사용하는 지표가 과거 봉수에 따라 현재값이 달라지는 유형이면
검색에 필요한 최소기간에 사용자가 봉수를 지정해 주셔야 합니다.
종목검색은 최대 제공봉수가 500봉입니다.
•
일반
설명 등을 입력하거나 볼 수 있는 화면입니다.
6.
종목검색 실행
작성된 종목검색식은
예스트레이더의 [3201]종목검색, [3202]파워종목검색이나
NH트레이더의 [5202] 종목검색에서 실행할 수 있습니다.
뒤로가기는 좌측상단의 목차 버튼을 눌러주세요.